Linktjekker
Skrevet af d. 7/12-2017 07:13

Tjek dine links

Har du mange links til eksterne sider på din hjemmeside, kan nedenstående script være en god måde at holde styr på hvilke links der stadig er relevante. Nedenstående script giver dig mulighed for at løbe alle din links igennem og returnere en status på linket. Hvis du trækker alle dine links på din hjemmeside fra en tabel i en database, kan du let holde styr på hvilke links der ikke længere virker og holde din side opdateret.
Se eksemplet her.

<%
' Array med URL'er, som skal chekkes
arrURLS = "http://www.jubii.dk" 
arrURLS = arrURLS & ",http://www.yahoo.dk"
arrURLS = arrURLS & ",http://www.google.dk"
arrURLS = Split(arrURLS,",")

' Array med HTTP header koder
arrHTTPcode = _
  Array("100", "101", "200", "201", "202", _
  "203", "204", "205", "206", "300", _
  "301", "302", "303", "304", "305", _
  "307", "400", "401", "402", "403", _
  "404", "405", "406", "407", "408", _
  "409", "410", "411", "412", "413", _
  "414", "415", "416", "417", "500", _
  "501", "502", "503", "504", "505") 

' Array med HTTP header kodernes forklaringer
arrHTTPtext = _
  Array("Continue", "Switching Protocols", _
  "OK", "Created", "Accepted", _
  "Non-Authoritative Information", _
  "No Content", "Reset Content", _
  "Partial Content", "Multiple Choices", _
  "Moved Permanently", "Found", "See Other", _
  "Not Modified", "Use Proxy", _
  "Temporary Redirect", "Bad Request", _
  "Unauthorized", "Payment Required", _
  "Forbidden", "Not Found", "Method Not Allowed", _
  "Not Acceptable", "Proxy Authentication Required", _
  "Request Time-out", "Conflict", "Gone", _
  "Length Required", "Precondition Failed", _
  "Request Entity Too Large", "Request-URI Too Large", _
  "Unsupported Media Type", _
  "Requested range not satisfiable", "Expectation Failed", _
  "Internal Server Error", "Not Implemented", _
  "Bad Gateway", "Service Unavailable", "Gateway Time-out", _
  "HTTP Version not supported") 

' Gennemløb Array med URL'er

Response.Write "<!DOCTYPE html PUBLIC '-//IETF//DTD HTML 2.0//EN'><html><title></title>"

Set objHttp = Server.CreateObject("WinHTTP.WinHTTPRequest.5.1")

For intURL = 0 to Ubound(arrURLS)
  
  On Error Resume Next
  
  objHttp.open "GET", arrURLS(intURL), false 
  objHttp.setRequestHeader "Content-type", "application/x-www-form-urlencoded"
  objHttp.setRequestHeader "User-Agent", "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1)" 
  objHttp.setRequestHeader "ACCEPT-LANGUAGE", "da"
  objHttp.setRequestHeader "Accept", "image/gif, image/x-xbitmap, image/jpeg, image/pjpeg, " & _
                           "application/vnd.ms-powerpoint, application/vnd.ms-excel, application/msword, */*" 
  objHttp.Send ""

  For intCode = 0 to Ubound(arrHTTPcode) 
    If Instr(objHttp.status,arrHTTPcode(intCode)) Then
      strResponse = arrHTTPtext(intCode)
      Exit For
    End if
  Next

  If Err.Number <> 0 Then
    strResponse = Err.Description
  End If
  
  Response.Write "<p>" & arrURLS(intURL) & " - " & strResponse & "</p>"
  Response.Flush
  
  strResponse = ""
Next

Set objHttp = Nothing
On Error Goto 0

Response.Write "</html>"
%>
(0 stemmer)
Denne artikel var til hjælp
Denne artikel var ikke til hjælp

Kommentarer (0)
Opret kommentar
 
 
Navn:
Email:
Kommentarer:
CAPTCHA Verificering 
 
Indtast teksten du ser på billedet i feltet herunder (CAPTCHA). Dette er påkrævet for at undgå automatiske registreringer og form afsendelser.

Referencer |  Om Azero |  Betingelser |  Job |  Presse |  Kontakt Azero

Azero A/S - CVR 28 10 17 59 - Skjørringvej 8 - 8464 Galten - Telefon 38 19 50 17
Danske Bank - Reg 4180 - Konto 0010092027 - SWIFT DABADKKK - IBAN DK7230000010092027

Copyright © 2000-2020. Azero A/S respekterer alle varemærker.
Priser er angivet eksklusive moms i DKK, der tages forbehold for trykfejl. Alt salg sker i henhold til vores betingelser.
1. Domaincheck - 2. Search - 3. NScheck - 4. NSlookup - 5. Lookup - 6. TraceRoute - 7. Query - 8. CheckWeb - (9. Flere)