Domæne checker
Skrevet af d. 13/12-2017 07:36

Domain checker

Med sockets kan man f.eks. lave en domæne checker, prøv f.eks. følgende link der kalder nedenstående kode: Tjek Azero domæne.

Koden

<%
' $Id: domaincheck.asp,v 1.5 2009/04/27 08:51:46 TJ Exp $

Dim strDomainName, objSocket, objRegex, booQueryInValid

Sub Whois(strDomain, strServer)

  Dim strReturn
  Response.Write("<a href=""http://www." & strDomain & """><h1>" & strDomain & "</h1></a>")

  On Error Resume Next
  ' Whois port is 43
  objSocket.Host = strServer & ":43"
  objSocket.Open()

  ' Send the query....
  objSocket.SendLine(strDomain)

  ' Wait for disconnect and output the buffer
  objSocket.WaitForDisconnect()
  
  If (Err.Number <> 0) Then
    strReturn = Err.Description
  Else
    strReturn = objSocket.Buffer
  End If  

  objSocket.Close()
  
  Response.Write("<blockquote><pre>" & strReturn & "</pre></blockquote>")

End Sub


Response.Write "<!DOCTYPE html PUBLIC '-//IETF//DTD HTML 2.0//EN'><html><title></title>"

strDomainName = Request.QueryString("Domain").item
If Len(strDomainName) = 0 Then strDomainName = "azero"

Set objRegex = New RegExp
objRegex.Global = True
objRegex.Pattern = "[^0-9a-zA-Z\-]"
booQueryInValid = objRegex.Test(strDomainName)
Set objRegex = Nothing

If NOT booQueryInValid Then
  Set objSocket = Server.CreateObject("Socket.TCP")
  Call whois(strDomainName & ".dk", "whois.dk-hostmaster.dk")
  Call whois(strDomainName & ".nu", "whois.nic.nu")
  Call whois(strDomainName & ".com", "whois.verisign-grs.com")
  Call whois(strDomainName & ".net", "whois.verisign-grs.com")
  Call whois(strDomainName & ".org", "whois.pir.org")
  Set objSocket = Nothing
Else
  Response.Write "Your query contains invalid characters."
End If

Response.Write "</html>"

%>
(0 stemmer)
Denne artikel var til hjælp
Denne artikel var ikke til hjælp

Kommentarer (0)
Opret kommentar
 
 
Navn:
Email:
Kommentarer:
CAPTCHA Verificering 
 
Indtast teksten du ser på billedet i feltet herunder (CAPTCHA). Dette er påkrævet for at undgå automatiske registreringer og form afsendelser.

Referencer |  Om Azero |  Betingelser |  Job |  Presse |  Kontakt Azero

Azero A/S - CVR 28 10 17 59 - Skjørringvej 8 - 8464 Galten - Telefon 38 19 50 17
Danske Bank - Reg 4180 - Konto 0010092027 - SWIFT DABADKKK - IBAN DK7230000010092027

Copyright © 2000-2020. Azero A/S respekterer alle varemærker.
Priser er angivet eksklusive moms i DKK, der tages forbehold for trykfejl. Alt salg sker i henhold til vores betingelser.
1. Domaincheck - 2. Search - 3. NScheck - 4. NSlookup - 5. Lookup - 6. TraceRoute - 7. Query - 8. CheckWeb - (9. Flere)