Http Get
Skrevet af d. 13/12-2017 07:41

HTTP GET

Hent data fra andre sider. For at bruge nedenstående kode behøver du kun ændre kaldet i den nederste linie. Test koden.

Koden

<%

' *** Get a file through HTTP ( GetHttp("www.azero.dk/forside.asp") )
Function GetHttp(strUrl)

  ' Reserve variables
  Dim strHost
  
   ' Start error handling
   On Error Resume Next

  ' Strip off http://
  If LCase(Left(strUrl, 7)) = "http://" Then
    strUrl = Right(strUrl, Len(strUrl) - 7)
  End If
  
  ' Split server address and filename
  If InStr(strUrl, "/") > 0 Then
    strHost = Left(strUrl, InStr(strUrl, "/") - 1 )
    strUrl = Right(strUrl, (Len(strUrl) - InStr(strUrl, "/")) + 1 )
  End If
  
  ' Add port if not included
  If InStr(strHost, ":") = 0 Then
    strHost = strHost & ":80"
  End If
  
   ' Create object
   set Socket = server.CreateObject("Socket.TCP")

   ' Set hostadress
   socket.Host = strHost

   ' Set timeout to 5 seconds
   Socket.TimeOut = 5000

   ' Open connection to host
   Socket.Open

   ' Send getline for content
  Socket.SendLine("GET /" & strUrl & " HTTP/1.0" & Chr(13) & Chr(10) & "Host: " & strHost & Chr(13) & Chr(10))

   ' Wait until content is recieved
   Socket.WaitForDisconnect()

   ' Insert data into function
   GetHttp = Socket.Buffer

   ' Close object
   Socket.Close()

   ' Error
   If Err.Number <> 0 Then
       Response.Write Err& ": " & Err.Description
       Response.Write "<br/>Host:[" & strHost & "]<br/>Url:[" & strUrl & "]"
       Exit function
   End If
   On Error Goto 0

End Function

' *** Get content within a tag (strS) ( GetHttpData("www.azero.dk/forside.asp", "body") )
Function GetHttpData(strUrl,strS)
  Dim strT
  strT = GetHttp(strUrl)
  strT = Mid(strT, InStr(LCase(strT), "<" & LCase(strS)))
  strT = Mid(strT, InStr(LCase(strT), ">") + 1)
  strT = Left(strT, InStrRev(LCase(strT), "</" & LCase(strS)) - 1)
  GetHttpData = strT
End Function

' *** Get the header from a file through HTTP ( GetHttpHeader("www.azero.dk/forside.asp") )
Function GetHttpHeader(strUrl)
  Dim strT
  strT = GetHttp(strUrl)
  strT = Mid(strT, 1, InStr(strT, Chr(13) & Chr(10) & Chr(13) & Chr(10)))
  GetHttpHeader = strT
End Function

' *** Get the body from a file through HTTP ( GetHttpBody("www.azero.dk/forside.asp") )
Function GetHttpBody(strUrl)
  Dim strT
  strT = GetHttp(strUrl)
  strT = Mid(strT, InStr(strT, Chr(13) & Chr(10) & Chr(13) & Chr(10)) + 4)
  GetHttpBody = strT
End Function


' Hent alt mellem <body> og </body> fra vores bestillingsside og udskriv det
Response.Write "<!DOCTYPE html PUBLIC '-//IETF//DTD HTML 2.0//EN'><html><title></title><pre>"
Response.Write GetHttpHeader("azero.dk/bestil/default.asp")
Response.Write "</pre></html>"

%>

Hvis du vil vide mere, så kig på Dimac.

(0 stemmer)
Denne artikel var til hjælp
Denne artikel var ikke til hjælp

Kommentarer (0)
Opret kommentar
 
 
Navn:
Email:
Kommentarer:
CAPTCHA Verificering 
 
Indtast teksten du ser på billedet i feltet herunder (CAPTCHA). Dette er påkrævet for at undgå automatiske registreringer og form afsendelser.

Referencer |  Om Azero |  Betingelser |  Job |  Presse |  Kontakt Azero

Azero A/S - CVR 28 10 17 59 - Skjørringvej 8 - 8464 Galten - Telefon 38 19 50 17
Danske Bank - Reg 4180 - Konto 0010092027 - SWIFT DABADKKK - IBAN DK7230000010092027

Copyright © 2000-2020. Azero A/S respekterer alle varemærker.
Priser er angivet eksklusive moms i DKK, der tages forbehold for trykfejl. Alt salg sker i henhold til vores betingelser.
1. Domaincheck - 2. Search - 3. NScheck - 4. NSlookup - 5. Lookup - 6. TraceRoute - 7. Query - 8. CheckWeb - (9. Flere)